Maison sécurisée par RFID

#include <SPI.h>          // Bibliothèque pour la communication SPI
#include <MFRC522.h>      // Bibliothèque du lecteur RFID RC522
#include <Servo.h>        // Bibliothèque pour contrôler le servomoteur
// ---------------------------
// Définition des broches
// ---------------------------
#define SS_PIN 10         // Broche SDA / SS du module RFID
#define RST_PIN 9         // Broche RESET du module RFID
#define SERVO_PIN 3       // Broche de commande du servomoteur
#define LED_G 4           // LED verte
#define LED_R 5           // LED rouge
#define BUZZER 2          // Buzzer
// ---------------------------
// Création des objets
// ---------------------------
MFRC522 mfrc522(SS_PIN, RST_PIN);   // Création de l’objet RFID
Servo myServo;                      // Création de l’objet servo
void setup() {
  // Initialisation de la communication série
  Serial.begin(9600);
  // Initialisation du bus SPI
  SPI.begin();
  // Initialisation du lecteur RFID
  mfrc522.PCD_Init();
  // Configuration des broches en sortie
  pinMode(LED_G, OUTPUT);
  pinMode(LED_R, OUTPUT);
  pinMode(BUZZER, OUTPUT);
  // Mise à l’état initial des sorties
  digitalWrite(LED_G, LOW);
  digitalWrite(LED_R, LOW);
  noTone(BUZZER);
  // Message affiché dans le moniteur série
  Serial.println("Presentez votre carte au lecteur...");
}
void loop() {
  // Vérifie si une nouvelle carte est présente
  if (!mfrc522.PICC_IsNewCardPresent()) return;
  // Vérifie si la carte peut être lue
  if (!mfrc522.PICC_ReadCardSerial()) return;
  // ---------------------------
  // Lecture de l'identifiant UID
  // ---------------------------
  String uid = "";
  for (byte i = 0; i < mfrc522.uid.size; i++) {
    // Ajoute un espace avant chaque octet
    uid += (mfrc522.uid.uidByte[i] < 0x10 ? " 0" : " ");
    uid += String(mfrc522.uid.uidByte[i], HEX);
  }
  // Conversion en majuscules
  uid.toUpperCase();
  // Supprime le premier espace
  uid = uid.substring(1);
  // Affiche l’UID dans le moniteur série
  Serial.print("UID : ");
  Serial.println(uid);
  // ---------------------------
  // Vérification des cartes autorisées
  // ---------------------------
  String nom = "";
  if (uid == "93 5D 67 25") {
    nom = "Lowen";
  }
  else if (uid == "03 C2 12 36") {
    nom = "Makoume";
  }
  // ---------------------------
  // Si la carte est autorisée
  // ---------------------------
  if (nom != "") {
    Serial.print("OK Bienvenue a : ");
    Serial.println(nom);
    // Allume la LED verte
    digitalWrite(LED_G, HIGH);
    // Émet un bip court
    tone(BUZZER, 500);
    delay(300);
    noTone(BUZZER);
    // Ouvre la porte avec le servomoteur
    myServo.attach(SERVO_PIN);
    myServo.write(180);
    delay(350);
    myServo.detach();
    // Attend 5 secondes avant de refermer
    delay(5000);
    // Referme la porte
    myServo.attach(SERVO_PIN);
    myServo.write(0);
    delay(315);
    myServo.detach();
    // Éteint la LED verte
    digitalWrite(LED_G, LOW);
  }
  // ---------------------------
  // Si la carte est refusée
  // ---------------------------
  else {
    Serial.println("Acces refuse");
    // Allume la LED rouge
    digitalWrite(LED_R, HIGH);
    // Émet un bip long
    tone(BUZZER, 300);
    delay(1000);
    noTone(BUZZER);
    // Éteint la LED rouge
    digitalWrite(LED_R, LOW);
  }
  // ---------------------------
  // Fin de communication avec la carte
  // ---------------------------
  mfrc522.PICC_HaltA();
  mfrc522.PCD_StopCrypto1();
  // Petite pause avant la prochaine lecture
  delay(1500);
}